This code will help to automatically update Access application distributed on network.

Option Compare Database
Option Explicit
' ***************************************
' Automatically update Access application distributed on network by using a autoinstaller
' ***************************************
' Copyright ┬ę 2012 De Zinger ICT
' ***************************************
' Instructions:
' Create an AutoExec macro which executes procedure AutoUpdate
' Change strNewVersionFolder to to an existing location where the new version resides
' Save Access project
' Copy this Access project to the new version location
' Alter constVersionCurrent to version 1.01 in the Access project in the new version location
' Run the original version 1.00
' ***************************************
' Best practise:
' Create an front and back-end application
' The front-end holds the front-end version in code
' The back-end holds then current version in a table, table is linked in front-end
' If front-end version differs from back-end version then run AutoUpdate
' ***************************************

Const constVersionCurrent As String = "1.00"
Const constVersionNew As String = "1.01"

Public Function AutoUpdate()
Dim strUpdateFile As String
Dim strCurrentVersion As String
Dim strRestart As String
Dim strNewVersion As String
Dim fso As Object

Const strNewVersionFolder As String = "C:\AutoUpdate\New Version\" 'Change this const to an existing location where the new version resides

    ' Create FileSystemObject using late binding
   Set fso = CreateObject("Scripting.FileSystemObject")
   
    ' sets the batch file name and location
   strUpdateFile = CurrentProject.Path & "\Update.cmd"
   
    If fso.FileExists(strUpdateFile) Then
        fso.deleteFile strUpdateFile, True
    End If
    Set fso = Nothing

    ' Perform versioncheck
   If constVersionCurrent <> constVersionNew Then

        ' set the current file name and location
       strCurrentVersion = CurrentProject.FullName
       
        ' sets the new file name and location
       strNewVersion = strNewVersionFolder & CurrentProject.Name
       
        ' creates the batch file
       Open strUpdateFile For Output As #1
        Print #1, "ECHO OFF"
        Print #1, "CLS"
        Print #1, "ECHO   UPDATING "
        Print #1, "PING 1.1.1.1 -n 1 -w 10000 >NUL"
        Print #1, "CLS"
        Print #1, "ECHO   UPDATING ."
        Print #1, "Del """ & strCurrentVersion & """"
        Print #1, "CLS"
        Print #1, "ECHO   UPDATING .."
        Print #1, "Copy /Y """ & strNewVersion & """ """ & strCurrentVersion & """"
        Print #1, "CLS"
        Print #1, "ECHO   UPDATING ..."
        Print #1, "START /I " & """MSAccess.exe"" " & """" & strCurrentVersion & """"
        Print #1, "CLS"
        Print #1, "ECHO   UPDATING ...."
        Close #1
         
        ' runs the batch file
       Shell strUpdateFile, vbNormalFocus
       
        'closes the current version, the batch file is still running
       DoCmd.Quit
   
    End If
   
End Function